! 7.5 钻杆的扭转自由振动
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）定义工程选项、单元类型、实常数和材料参数
/FILNAME, EX7.5
/PREP7
/TITLE, EX7.5(1), TORSIONAL FREQUENCIES OF A DRILL PIPE WITH PIPE16 ELEMENT.
ET, 1, PIPE16
ET, 2, MASS21
R, 1, 0.1143, 0.0085
R, 2, , , , , , 39.73
MP, EX, 1, 215.134E9
MP, DENS, 1, 7855.3
MP, NUXY, 1, 0.3
! （2）定义模型节点和单元连接关系
/VIEW, 1, 1, 1, 1
N, 1
N, 13, , , -1524
FILL
E, 1, 2
EGEN, 12, 1, 1
TYPE, 2
REAL, 2
E, 13
FINISH
! （3）进入求解模块, 指定输出选项和位移约束
/SOLU
ANTYPE, MODAL
MODOPT, SUBSP, 2
D, 1, UX, , , 13, , UY, UZ, ROTX, ROTY
D, 1, ROTZ
! （4）设置输出第1阶频率信息, 并开始求解
OUTPR, , 1
SOLVE
FINISH
! （5）进入后处理模块, 提取前两阶频率的计算结果
/POST1
*GET, FREQ1, MODE, 1, FREQ
*GET, FREQ2, MODE, 2, FREQ
*STATUS, PARM
FINISH
! （6）重新进入前处理模块, 将单元类型改变为BEAM4, 重新分析该振动问题
/PREP7
/TITLE, EX7.5(2), TORSIONAL FREQUENCIES OF A DRILL PIPE WITH BEAM4 ELEMENT.
ET, 1, BEAM4
R, 1, 0.0028283, 3.982E-6, 3.982E-6, 0.1143, 0.1143 0.1143m.
RMORE, , 7.962E-6
FINISH
! （7）进入求解模块, 指定模态分析的选项, 并开始求解
/SOLU
MODOPT, REDUC, 2, , , 2
M, 2, ROTZ, 13
SOLVE
FINISH
! （8）进入一般后处理模块, 提取频率计算结果
/POST1
*GET, FREQ1, MODE, 1, FREQ
*GET, FREQ2, MODE, 2, FREQ
*STATUS, PARM
FINISH
