!7.5 钻杆的扭转自由振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,单元类型,实常数和材料参数
/FileName, EX7.5
/PREP7
/TITLE, EX7.5, TORSIONAL FREQUENCIES OF A DRILL PIPE
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND., PAGE 272, EX. 8.4-5
C*** 使用直线管单元PIPE16计算
ET,1,PIPE16
ET,2,MASS21
R,1,0.1143,0.0085
R,2,,,,,, 39.73
MP,EX,1,215.134E9
MP,DENS,1,7855.3
MP,NUXY,1,0.3
! (2) 定义模型节点和单元连接关系
/VIEW,1,1,1,1
N,1
N,13,,,-1524
FILL
E,1,2
EGEN,12,1,1
TYPE,2
REAL,2
E,13
FINISH
! (3) 进入求解模块,指定输出选项和位移约束
/SOLU
ANTYPE,MODAL
MODOPT,SUBSP,2
D,1,UX,,,13,,UY,UZ,ROTX,ROTY
D,1,ROTZ
! (4) 设置输出第1阶频率的默认信息,并开始求解
OUTPR,,1
SOLVE
FINISH
! (5) 进入后处理模块,提取前两阶频率的计算结果
/POST1
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
! (6) 定义数组变量,将计算结果输出到文本文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = ' f1',' f2'
LABEL(1,2) = ', Hz ',', Hz '
*VFILL,VALUE(1,1),DATA,0.384,1.26
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/0.384),ABS(FREQ2/1.26)
SAVE, TABLE_1
FINISH
! (7) 重新进入前处理模块,将单元类型改变为BEAM4,重新分析该振动问题
/PREP7
C**** 使用梁单元BEAM4
ET,1,BEAM4
R,1,0.0028283,3.982E-6,3.982E-6,0.1143, 0.1143
RMORE,,7.962E-6
FINISH
! (8) 进入求解模块,指定模态分析的选项,并开始求解
/SOLU
MODOPT,REDUC,2,,,2
M,2,ROTZ,13
SOLVE
FINISH
! (9) 进入一般后处理模块,提取频率计算结果
/POST1
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
! (10) 定义数组变量,将计算结果输出到文本文件
LABEL(1,1) = 'UR(INNER'
LABEL(1,2) = ' RAD),in'
*VFILL,VALUE(1,1),DATA,.384,1.26
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/.384),ABS(FREQ2/1.26)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT, EX7_5, out
/COM,------------------- EX7.5 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING PIPE16 ELEMENTS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING BEAM4 ELEMENTS:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.4,' ',F10.4,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX7_5, out
