! 8.5 固支圆板的自由振动
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART ! 清除数据, 不加载初始化文件
! （1）设置工程选项、单元类型、材料参数
/FILNAME, EX8.5 ! 定义文件名称
/PREP7 ! 加载前处理模块
SMRT, OFF ! 关闭智能化网格功能
/TITLE, EX8.5, NATURAL FREQUENCY OF A FLAT CIRCULAR PLATE WITH CLAMPED EDGE.
ET, 1, PLANE2, , , 1 ! 使用轴对称平面单元PLANE2
MP, EX, 1, 207E9 ! 定义第1类材料的弹性模量EX ＝ 207 GPa
MP, PRXY, , 0.3 ! 定义材料的泊松比为PRXY ＝ 0.3
MP, DENS, 1, 7801.6 ! 定义第1类材料的密度DENS = 7801.6 kg/m^3
! （2）定义关键点、线和面, 并将面剖分为面单元
K, 1 ! 在坐标原点(0, 0, 0)定义第1个关键点
K, 2, 0.4318 ! 在坐标(0.4318m, 0)定义第2个关键点
KGEN, 2, 1, 2, 1, , 0.0127 ! 循环2次, 按照节点1到节点2的坐标, Y坐标增加12.7mm
L, 1, 2 ! 过关键点1, 2定义直线
L, 3, 4 ! 过关键点3, 4定义直线
LESIZE, ALL, , , 10 ! 所有直线在剖分单元时, 剖分为10段
ESIZE, , 1 ! 单元尺寸为剖分为1段
A, 1, 2, 4, 3 ! 过节点1, 2, 3和4定义面
AMESH, 1 ! 对1号面进行面单元剖分
! （3）选择边界节点, 施加位移约束
NSEL, R, LOC, X, 0 ! 重新选择位于X＝0的节点
D, ALL, UX ! 对所有节点的X方向位移施加位移约束UX＝0
NSEL, ALL ! 选择所有节点
DK, 2, ALL, , , 1 ! 约束2号关键点的所有自由度, 并将其标识为约束展开
DK, 4, UX, , , 1 ! 约束4号关键点的UX自由度, 并将其标识为约束展开
FINISH ! 退出前处理模块PREP7
! （4）指定求解类型和求解方法后, 开始模态分析的求解
/SOLU ! 加载求解模块
ANTYPE, MODAL ! 指定分析类型为模态分析
MODOPT, SUBSP, 9 ! 指定使用子空间迭代法求解器, 展开前9解模态
EQSLVE, PCG ! 指定方程求解器为PCG（预条件的共轭梯度循环求解器）
SOLVE ! 开始模态分析的求解
! （5）提取频率计算结果
*GET, F1, MODE, 1, FREQ ! 提取第1阶频率, 存入变量F1
*GET, F2, MODE, 2, FREQ ! 提取第2阶频率, 存入变量F2
*GET, F3, MODE, 3, FREQ ! 提取第3阶频率, 存入变量F3
*STATUS, PARM ! 查看保存到变量中的计算结果
FINISH ! 退出求解模块SOLU
