motorola 针对coldfire 5275 评估板的Dbug bootloader源程序

				#/*
				# * File:		sdram.lcf
				# * Purpose:	Linker file for the M5275EVB
				# *
				# * Notes:		dBUG running in SDRAM
				# *
				# */
				
				MEMORY
				{
				    text    (RX) : ORIGIN = 0x00000480,  LENGTH = 0
				    data    (RW) : ORIGIN = AFTER(text), LENGTH = 0
				    bss     (RW) : ORIGIN = AFTER(data), LENGTH = 0
				}
				
				SECTIONS
				{
				    ___IPSBAR			= 0x40000000;
				
				    ___SDRAM			= 0x00000000;
				    ___SDRAM_SIZE		= (16 * 1024 * 1024);
				
				    ___SRAM				= 0x20000000;
				    ___SRAM_SIZE		= (64 * 1024);
				
				    ___EXT_SRAM			= 0x30000000;
				    ___EXT_SRAM_SIZE	= (512 * 1024);
				
				    ___FLASH			= 0xFFE00000;
				    ___FLASH_SIZE		= (2 * 1024 * 1024);
				
				    ___PARAMS			= 0xFFE04000;
				    ___PARAMS_SIZE		= 0x50;
				
				    ___VECTOR_RAM		= 0x00000000;
				
				    ___DBUG_ADDRESS		= ADDR(text);
				
					.text :
					{
						. 				= ALIGN(0x10);
						vectors.s (.text)
						*(.text)
						. 				= ALIGN(0x10);
					} > text
				
					.data :
					{
						. 				= ALIGN(0x10);
						___DATA_ROM 	= .;
						___DATA_RAM 	= .;
						*(.rodata)	
						*(.sdata)
						*(.data)
						*(.relocate_code)
						*(.relocate_const)
						*(.relocate_data)
						. 				= ALIGN(0x10);
						___DATA_END 	= .;
					} > data
					
					.bss :
					{
						. 					= ALIGN(0x10);
						___BSS_START 		= .;
						*(.sbss)
						*(SCOMMON)
						*(.bss)
						*(COMMON)
						___BSS_END 			= .;
						. 					= ALIGN(0x10);
						___HEAP_START		= .;
						.					= . + (92 * 1024);
						___HEAP_END			= .;
						___PARAMS_START		= .;
						.					= . + ___PARAMS_SIZE;
						___PARAMS_END		= .;
						___SP_END			= .;
						.					= . + (4 * 1024);
						___SP_INIT			= .;
					    .                   = (. + 0xFFFF) & 0xFFFF0000;
					    ___DBUG_SIZE        = . - ___DBUG_ADDRESS;
					    ___USER_SPACE		= .;
					    ___USER_SPACE_SIZE	= ___SDRAM_SIZE - .;
					} > bss
				}