CodeWarrior IDE!COLDFIRE 5275源程序!

				#/*
				# * File:		sdram.lcf
				# * Purpose:	Linker file for the M5275EVB
				# *
				# * Notes:		Project running in SDRAM
				# *
				# */
				
				MEMORY 
				{
					sdram		(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x01000000
					vector_ram	(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x00000400
					user		(RWX)	: ORIGIN = 0x00020000, LENGTH = 0x00FE0000
					sram		(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00010000
					ext_sram	(RWX)	: ORIGIN = 0x30000000, LENGTH = 0x00080000
					ipsbar		(RWX)	: ORIGIN = 0x40000000, LENGTH = 0x40000000
					ext_flash	(RWX)	: ORIGIN = 0xFFE00000, LENGTH = 0x00200000
				}
				
				SECTIONS 
				{
					.sdram		: {} > sdram
					.vector_ram	: {} > vector_ram
					.ipsbar		: {} > ipsbar
					.sram		: {} > sram
					.ext_sram	: {} > ext_sram
					.ext_flash	: {} > ext_flash
					
					.vectors :
					{
						vectors.s (.text)
					} > user
				
					.text :
					{
						. = ALIGN (0x10);
						*(.text)
						. = ALIGN (0x10);
						*(.rodata)
					} >> user
				
					.data :
					{  
						___DATA_ROM = .;
						___DATA_RAM = .;
						. = ALIGN (0x10);
						*(.data)
						. = ALIGN (0x10);
						*(.sdata)
						___DATA_END = .;
					} >> user
					
					.bss :
					{
						. = ALIGN (0x10);
						___BSS_START = .;
						*(.sbss)
						*(SCOMMON)
						*(.bss)
						*(COMMON)
						___BSS_END = .;
					} >> user
					
					.custom :
					{
						. = ALIGN (0x10);
						___HEAP_START	= .;
						___HEAP_END		= .;
						___SP_END		= .;
						.				= . + 0x1000;
						___SP_INIT		= .;
					} >> user
					
					___IPSBAR			= ADDR(.ipsbar);
					___VECTOR_RAM		= ADDR(.vector_ram);
				
					___SDRAM			= ADDR(.sdram);
					___SDRAM_SIZE		= 0x01000000;
				
					___SRAM				= ADDR(.sram);
					___SRAM_SIZE		= 0x00010000;
				
					___EXT_SRAM			= ADDR(.ext_sram);
					___EXT_SRAM_SIZE	= 0x00080000;
				
					___EXT_FLASH		= ADDR(.ext_flash);
					___EXT_FLASH_SIZE	= 0x00200000;
				}