COLDFIRE 5282SC的文件

				/*
				 * File:		sdram.dld
				 * Purpose:		Linker file for the M5282EVB
				 *
				 * Notes:		Project running in SDRAM
				 *
				 */
				
				MEMORY
				{
					sdram		: org = 0x00000000, len = 0x01000000
					user		: org = 0x00010000, len = 0x00FF0000
					sram		: org = 0x20000000, len = 0x00010000
					vector_ram	: org = 0x20000000, len = 0x00000400
					ext_sram	: org = 0x30000000, len = 0x00080000
					ipsbar		: org = 0x40000000, len = 0x40000000
					flash 		: org = 0xF0000000, len = 0x00080000	
					ext_flash 	: org = 0xFFE00000, len = 0x00200000	
				}
				
				SECTIONS
				{
					GROUP :
					{
						.text :
						{
							vectors.o (.text)
							*(.text)
							*(.rdata)
							*(.rodata)
						}
				
						.data :
						{
							___DATA_ROM = .;
							___DATA_RAM = .;
							*(.data)
							*(.sdata)
							___DATA_END = .;
						}
				
						.bss (BSS) :
						{
							___BSS_START = .;
							*(.bss)
							*(.sbss)
							___BSS_END = .;
							___HEAP_START	= .;
							.				= . + (32*1024);
							___HEAP_END		= .;
							___SP_END		= .;
							.				= . + (4*1024);
							___SP_INIT		= .;
						}
					} > user
				}
				
				/* 
				 * Memory Map information for use in source files
				 */
				___IPSBAR			= ADDR(ipsbar);
				___VECTOR_RAM		= ADDR(vector_ram);
				
				___SDRAM			= ADDR(sdram);
				___SDRAM_SIZE		= SIZEOF(sdram);
				
				___SRAM				= ADDR(sram);
				___SRAM_SIZE		= SIZEOF(sram);
				
				___EXT_SRAM			= ADDR(ext_sram);
				___EXT_SRAM_SIZE	= SIZEOF(ext_sram);
				
				___FLASH			= ADDR(flash);
				___FLASH_SIZE		= SIZEOF(flash);
				
				___EXT_FLASH		= ADDR(ext_flash);
				___EXT_FLASH_SIZE	= SIZEOF(ext_flash);