!2.5 圆形截面悬臂杆的弯扭组合变形
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
/FileName, EX2.5
/PREP7
/TITLE, EX2.5, COMBINED BENDING AND TORSION OF PIPE WITH PIPE16 ELEMENT
C*** STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 299, PROB. 2
ANTYPE,STATIC
ET,1,PIPE16
R,1,118.62,59.31
MP,EX,1,207E3
MP,NUXY,1,0.3
/VIEW,1,1,1,1
N,1
N,2,,,7620
E,1,2
D,1,ALL
F,2,MZ,1112*914
F,2,FX,-1112
FINISH
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
/POST1
ETABLE,P_STRS,NMISC,86
ETABLE,SHR,NMISC,88
*GET,P_STRSS,ELEM,1,ETAB,P_STRS
*GET,SHEAR,ELEM,1,ETAB,SHR
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'MAX PRIN','MAX SH S'
LABEL(1,2) = ' STRS MPa','TRS MPa '
*VFILL,VALUE(1,1),DATA,51.653,25.93
*VFILL,VALUE(1,2),DATA,P_STRSS,(SHEAR/2)
*VFILL,VALUE(1,3),DATA,ABS(P_STRSS/51.653 ) ,ABS((SHEAR/2)/25.93 )
/COM
/OUT, EX2_5, out
/COM,------------------- EX2.5 RESULTS COMPARISON ----------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST, EX2_5, out
