!2.3 矩形截面梁的纵横弯曲分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
/PREP7
/FileName, EX2.3
/TITLE, EX2.3, TIE ROD WITH LATERAL LOADING, NO STREES STIFFENING
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 42, ART. 6
! (1) 定义求解类型，实常数和材料参数
ANTYPE,STATIC
ET,1,BEAM4,,,,,,1
R,1,0.403225e-2, 0.135492e-5, 0.135492e-5, 0.0635, 0.0635
MP,EX,1,210E9
MP,PRXY,,0.3
! (2) 定义节点位置
N,1
N,5,2.54
FILL
! (3) 定义单元连接关系
E,1,2
EGEN,4,1,1
! (4) 定义位移约束和荷载条件
D,ALL,UY,,,,,ROTX,ROTZ
D,1,UZ
NSEL,S,,,5
DSYM,SYMM,X
NSEL,ALL
! (5) 施加荷载
F,1,FX,-97740
SFBEAM,ALL,1,PRES,314
FINISH
! (6) 进入求解模块，开始求解
/SOLU
SOLVE
FINISH
! (7) 进入后处理模块，显示位移计算结果，提取左边支座节点的转角和跨中挠度
/POST1
NSEL,S,,,1,5,4
PRNSOL,U,Z
PRNSOL,ROT,Y
NSEL,ALL
PRRSOL
RGHT_END = NODE (2.54,0,0)
LFT_END = NODE (0,0,0)
*GET,UZ_MX_C2,NODE,RGHT_END,U,Z
*GET,SLOPE_C2,NODE,LFT_END,ROT,Y
FINISH
! (8) 在时间历程后处理器中，叠加处理5号节点的弯矩
/POST26
RFORCE,2,RGHT_END,M,Y
STORE
*GET,M_MX_C2,VARI,2,EXTREM,VMAX
FINISH
! (9) 重新进入前处理模块，重新计算考虑应力强化效应的压杆
/PREP7
/TITLE, EX2.3(2), TIE ROD WITH LATERAL LOADING, STRESS STIFFENING PRESENT
SSTIF,ON
NSUBST,5
AUTOTS,ON
FINISH
! (10) 进入求解模块，制定最小收敛误差后，开始非线性求解
/SOLU
CNVTOL,F,,.0001,,1
SOLVE
FINISH
! (11) 进入后处理模块，显示位移计算结果，提取左边支座节点的转角和跨中挠度
/POST1
NSEL,S,,,1,5,4
PRNSOL,U,Z
PRNSOL,ROT,Y
PRRSOL
*GET,UZ_MX_C1,NODE,RGHT_END,U,Z
*GET,SLOPE_C1,NODE,LFT_END,ROT,Y
FINISH
! (12) 在时间历程后处理器中，叠加处理跨中（5号节点的）弯矩
/POST26
RFORCE,2,RGHT_END,M,Y
STORE
*GET,M_MX_C1,VARI,2,EXTREM,VMAX
! (13) 生成计算结果文本文件EX21.out
*DIM,LABEL,CHAR,3,2
*DIM,VALUE_C1,,3,3
*DIM,VALUE_C2,,3,3
LABEL(1,1) = 'UZ MAX ','SLOPE ','MOMENT M'
LABEL(1,2) = '(m) ','(rad) ','AX N-m'
*VFILL,VALUE_C1(1,1),DATA,-0.0050274,.00321,-521.52
*VFILL,VALUE_C1(1,2),DATA,UZ_MX_C1,SLOPE_C1,M_MX_C1
*VFILL,VALUE_C1(1,3),DATA,ABS(UZ_MX_C1/0.0050274),ABS(SLOPE_C1/.00321), ABS(M_MX_C1/521.52)
*VFILL,VALUE_C2(1,1),DATA,-0.00957,.006028,-1013
*VFILL,VALUE_C2(1,2),DATA,UZ_MX_C2,SLOPE_C2,M_MX_C2
*VFILL,VALUE_C2(1,3),DATA,ABS(UZ_MX_C2/0.00957),ABS(SLOPE_C2/.006028), ABS(M_MX_C2/1013)
/COM
/OUT, EX2_3, out
/COM,------------------- EX2.3 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS FOR F0 (STIFFENED):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,' ',F17.7,' ',F17.7,' ',1F5.3)
/COM,
/COM,RESULTS FOR F=0 (UNSTIFFENED):
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,' ',F17.7,' ',F17.7,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST, EX2_3, out
