!6.6 圆筒在一对横向集中力作用下的变形
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 设置工程选项,分析类型,实常数,材料参数
/FileName,EX6.6
/PREP7
smrt,off
/TITLE, EX6.6, PINCHED CYLINDER UNDER CONCENTRATED FORCE
/COM, REF: COOK, CONCEPTS AND APPL. OF FEA 2ND ED., 1981, PP. 284-287.
ANTYPE,STATIC
ET,1,SHELL93
R,,2.3876
MP,EX,,72.4E3
MP,NUXY,,0.3125
! (2) 在柱坐标系下定义关键点,柱面并对其进行单元划分
CSYS,1
K,1,125.8
K,2,125.8,,131.5
KGEN,2,1,2,1,,90
A,1,2,4,3
ESIZE,,8
/View,1,1,1,1
AMESH,1
! (3)在直角坐标系下定义约束
CSYS,0
NSEL,S,LOC,X,0
DSYM,SYMM,X,0
NSEL,S,LOC,Y,0
DSYM,SYMM,Y,0
NSEL,S,LOC,Z,0
DSYM,SYMM,Z,0
NSEL,ALL
FK,3,FY,-111.2
FINISH
! (4)在求解模块求解
/SOLU
SOLVE
FINISH
! (5)在后处理模块显示节点位移计算结果
/POST1
NSEL,S,LOC,Y,125.8
NSEL,R,LOC,Z,0
NSEL,R,LOC,X,0
PRNSOL,U,COMP
TOP_NODE = NODE(125.8,90,0)
*GET,DISP,NODE,TOP_NODE,U,Y
! (6) 定义数组,将计算结果保存到数组,然后将数组内容输出的计算结果文件
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1) = 'DEF_mm'
*VFILL,VALUE(1,1),DATA,2.893
*VFILL,VALUE(1,2),DATA,ABS(DISP)
*VFILL,VALUE(1,3),DATA,ABS(DISP/2.893)
SAVE, TABLE_1
FINISH
! (7)改变单元重新计算
/CLEAR,NOSTART
/FileName,EX6.6a
/PREP7
/TITLE, EX6.6a, PINCHED CYLINDER UNDER CONCENTRATED FORCE(SHELL150)
smrt,off
ANTYPE,STATIC
ET,1,SHELL150
R,,2.3876
MP,EX,,72.4E3
MP,NUXY,,0.3125
! (8) 在柱坐标系下定义关键点,柱面并对其进行单元划分
CSYS,1
K,1,125.8
K,2, 125.8,,131.44
KGEN,2,1,2,1,,90
A,1,2,4,3
ESIZE,,8
/View,1,1,1,1
AMESH,1
! (9) 在直角坐标系下定义约束
CSYS,0
NSEL,S,LOC,X,0
DSYM,SYMM,X,0
NSEL,S,LOC,Y,0
DSYM,SYMM,Y,0
NSEL,S,LOC,Z,0
DSYM,SYMM,Z,0
NSEL,ALL
FK,3,FY,-111.21
FINISH
! (10) 在求解模块求解
/SOLU
SOLVE
FINISH
! (11) 在后处理模块显示节点位移计算结果
/POST1
SET,1
NSEL,S,LOC,Y,125.8
NSEL,R,LOC,Z,0
NSEL,R,LOC,X,0
PRNSOL,U,COMP
TOP_NODE = NODE(125.8,90,0)
*GET,DISP,NODE,TOP_NODE,U,Y
! (12) 定义数组,将计算结果保存到数组,然后将数组内容输出的计算结果文件
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1) = 'DEF_mm'
*VFILL,VALUE(1,1),DATA,2.893
*VFILL,VALUE(1,2),DATA,ABS(DISP)
*VFILL,VALUE(1,3),DATA,ABS(DISP/2.893)
SAVE, TABLE_2
RESUME,TABLE_1
/COM
/OUT, EX6_6, out
/COM,------------------- EX6.6 RESULTS COMPARISON ---------------------
/COM,
/COM,SHELL93 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A10,' ',F10.3,' ',F10.3,' ',1F10.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,SHELL150
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A10,' ',F10.3,' ',F10.3,' ',1F10.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DEL,TABLE_1
/DEL,TABLE_2
FINISH
*LIST, EX6_6, out
