!5.4 圆柱形薄壳在均匀内压作用下的静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,分析类型,单元类型,实常数和材料参数
/FileName, EX5.4
/PREP7
/TITLE, EX5.4, CYLINDRICAL MEMBRANE UNDER PRESSURE
C*** STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 121, ART. 25
ANTYPE,STATIC
ET,1,SHELL41
R,1,25.4
MP,EX,1,207E3
MP,NUXY,1,0.3
! (2) 在柱坐标系下,定义节点和单元
CSYS,1
/View,1,1,1,1
N,1,1524
N,2,1524,,254
NGEN,2,2,1,2,1,,10
NROTAT,ALL
E,1,2,4,3
! (3) 定义耦合自由度,位移约束和荷载力
CP,1,UX,1,2,3,4
CP,2,UZ,2,4
D,1,UZ,,,3,2
D,ALL,UY
SFE,1,4,PRES,,-103.43*25.4
SFE,1,1,PRES,,-3.447575
FINISH
! (4)在求解模块,设置求解选项后求解
/SOLU
OUTPR,,1
SOLVE
FINISH
! (5)在后处理模块中提取应力计算结果
/POST1
*GET,STRS_HOP,NODE,1,S,2
*GET,STRS_AX,NODE,1,S,1
! (6)定义数组变量,通过这些变量将计算结果输出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'AXIAL ST','HOOP STR'
LABEL(1,2) = 'RSS MPa ','SS MPa '
*VFILL,VALUE(1,1),DATA,103.43,206.86
*VFILL,VALUE(1,2),DATA,STRS_HOP,STRS_AX
*VFILL,VALUE(1,3),DATA,ABS(STRS_HOP/103.43),ABS(STRS_AX/206.86)
/COM
/OUT, EX5_4, out
/COM,------------------- EX5.4 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.3,' ',F10.3,' ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST, EX5_4, out
