!5.2 圆形薄膜大变形静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 设置工程选项,单元类型,实常数和材料参数
/FileName,EX5.2
/PREP7
/TITLE, EX5.2, LARGE DEFLECTION OF A CIRCULAR MEMBRANE
C*** THEORY OF PLATES AND SHELLS, TIMOSHENKO, P. 404, EQ. 236
ET,1,SHELL51,,,,1
R,1,2.54e-3
MP,EX,1,207E3
MP,NUXY,1,0.25
MP,ALPX,1,0.556E-5
! (2)定义节点和单元
N,1
N,11,254
FILL
E,1,2
EGEN,10,1,1
FINISH
! (3)在求解模块,设置求解选项,施加位移约束后求解
/SOLU
ANTYPE,STATIC
NLGEOM,ON
SSTIF,ON
CNVTOL,F,,,,4
OUTPR,,LAST
TUNIF,-50
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,ALL
D,11,ALL
SOLVE
! (4)设置递增步长荷载,循环求解
KBC,1
SF,ALL,PRES,689.5e-6
SOLVE
! (5)移去温度应力,在求解
TUNIF,0
SOLVE
! (6)在后处理模块,定义单元表,提取单元应力计算结果
/POST1
SET,3
*GET,UY,NODE,1,U,Y
ESEL,S,ELEM,,1,1
ETABLE,CENT,LS,5
ESORT,CENT
*GET,PRSCNT,SORT,,MAX
ESEL,S,ELEM,,10,10
ETABLE,CEN,LS,5
ESORT,CEN
*GET,PRSOUT,SORT,,MAX
*status,parm
! (7)定义数组变量,通过这些变量将计算结果保存到文件
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'Y DISP ','PRES CENT ','PRES RIM'
LABEL(1,2) = ' mm',' MPa',' MPa'
*VFILL,VALUE(1,1),DATA,-11.656,420.75,326.25
*VFILL,VALUE(1,2),DATA,UY,PRSCNT,PRSOUT
*VFILL,VALUE(1,3),DATA,ABS(UY/11.656),ABS(PRSCNT/420.75),ABS(PRSOUT/326.25)
/COM
/OUT, EX5_2, out
/COM,------------------- EX5.2 RESULTS COMPARISON --------------
/COM,
/COM, LOAD STEP 3 | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F10.2,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX5_2, out
