motorola 针对coldfire 5275 评估板的Dbug bootloader源程序

				#
				#  File:		flash.lcf
				#  Purpose:	    Linker file for the M5275EVB
				# 
				#  Notes:		For use with a part programmer.
				# 
				# 
				
				MEMORY
				{
					dbug_ram	(RWX)	: ORIGIN = 0x00000400, LENGTH = 0x0001FC00
					vectors	    (R)     : ORIGIN = 0xFFE00000, LENGTH = 0x00004000
					params		(R) 	: ORIGIN = 0xFFE04000, LENGTH = 0x00002000
					dbug_rom	(RX)	: ORIGIN = 0xFFE06000, LENGTH = 0x0003C000
				}
				
				SECTIONS
				{
				    ___IPSBAR			= 0x40000000;
				
				    ___SDRAM			= 0x00000000;
				    ___SDRAM_SIZE		= (16 * 1024 * 1024);
				
				    ___SRAM				= 0x20000000;
				    ___SRAM_SIZE		= (64 * 1024);
				
				    ___EXT_SRAM			= 0x30000000;
				    ___EXT_SRAM_SIZE	= (512 * 1024);
				
				    ___FLASH			= 0xFFE00000;
				    ___FLASH_SIZE		= (2 * 1024 * 1024);
				
				    ___PARAMS			= ADDR(params);
				    ___PARAMS_SIZE		= 0x50;
				
				    ___VECTOR_RAM		= ___SDRAM;
				
				    ___DBUG_ADDRESS		= ___FLASH;
				    ___DBUG_SIZE		= 0x00040000;
				
				    ___USER_SPACE		= 0x00020000;
				    ___USER_SPACE_SIZE	= ___SDRAM + ___SDRAM_SIZE - ___USER_SPACE;
				
					.vectors :
					{
				        .               = ALIGN(0x10);
						vectors.s (.text)
					} > vectors
				
					.params :
					{
				        .               = ALIGN(0x10);
						params.c (.rodata)
					} > params
				
					.text :
					{
				        .               = ALIGN(0x10);
						*(.text)
						*(.rodata)	
				        .               = ALIGN(0x10);
						___DATA_ROM = .;
					} > dbug_rom
				
					.ram : AT(___DATA_ROM)
					{
				        .               = ALIGN(0x10);
						___DATA_RAM 	= .;
						*(.sdata)
						*(.data)
						*(.relocate_code)
						*(.relocate_const)
						*(.relocate_data)
						___DATA_END 	= .;
				        .               = ALIGN(0x10);
						___BSS_START 	= .;
						*(.sbss)
						*(.bss)
						___BSS_END 		= .;
				        .               = ALIGN(0x10);
						___HEAP_START	= .;
						.				= . + (92 * 1024);
						___HEAP_END		= .;
						___PARAMS_START	= .;
						.				= . + ___PARAMS_SIZE;
						___PARAMS_END	= .;
						___SP_END		= .;
						.				= . + (4 * 1024);
						___SP_INIT		= .;
					} > dbug_ram
				}