This is a book about vb.you could learn this from this book

				
				
				
				
				
				
				
				
				
				The DataSet Object with Multiple Tables
				
				
				
				The DataSet Object with Multiple Tables
				
				
								
				
				Connection string: 
				Books SELECT command: 
				Authors SELECT command: 
				Prices SELECT command: 
				 
				
				DataSet.Tables Collection
				
				DataSet.Relations Collection
				
				Contents of DataSet.Tables("Books")
				
				Contents of DataSet.Tables("Authors")
				
				Contents of DataSet.Tables("Prices")
				
				
				
				
				Sub Page_Load()
				
				   'get connection string from ..\global\connect-strings.ascx user control
				   Dim strConnect As String
				   strConnect = ctlConnectStrings.SQLConnectionString
				   outConnect.innerText = strConnect 'and display it
				
				   'specify the SELECT statement to extract the BookList data
				   Dim strSelectBooks As String
				   strSelectBooks = "SELECT * FROM BookList WHERE ISBN LIKE '18610033%'"
				   outSelectBooks.innerText = strSelectBooks   'and display it
				
				   'specify the SELECT statement to extract the BookAuthor data
				   Dim strSelectAuthors As String
				   strSelectAuthors = "SELECT * FROM BookAuthors WHERE ISBN LIKE '18610033%'"
				   outSelectAuthors.innerText = strSelectAuthors   'and display it
				
				   'specify the SELECT statement to extract the BookPrices data
				   Dim strSelectPrices As String
				   strSelectPrices = "SELECT * FROM BookPrices WHERE ISBN LIKE '18610033%'"
				   outSelectPrices.innerText = strSelectAuthors   'and display it
				
				   'declare a variable to hold a DataSet object
				   'note that we have to create it outside the Try..Catch block
				   'as this is a separate block and so is a different scope
				   Dim objDataSet As New DataSet()
				
				   Try
				
				      'create a new Connection object using the connection string
				      Dim objConnect As New SqlConnection(strConnect)
				
				      'create a new Command object
				      Dim objCommand As New SqlCommand()
				
				      'set the properties
				      objCommand.Connection = objConnect
				      objCommand.CommandType = CommandType.Text
				      objCommand.CommandText = strSelectBooks
				
				      'create a new DataAdapter object
				      Dim objDataAdapter As New SqlDataAdapter()
				      'and assign the Command object to it
				      objDataAdapter.SelectCommand = objCommand
				
				      'get the data from the "BookList" table in the database and
				      'put it into a table named "Books" in the DataSet object
				      objDataAdapter.Fill(objDataSet, "Books")
				
				      'change the SELECT statement in the Command object
				      objCommand.CommandText = strSelectAuthors
				      'then get data from "BookAuthors" table into the DataSet
				      objDataAdapter.Fill(objDataSet, "Authors")
				
				      'and do the same again to get the "BookPrices" data
				      objCommand.CommandText = strSelectPrices
				      objDataAdapter.Fill(objDataSet, "Prices")
				
				   Catch objError As Exception
				
				      'display error details
				      outError.innerHTML = "* Error while accesing data." _
				          & objError.Message & "" & objError.Source
				      Exit Sub  ' and stop execution
				
				   End Try
				
				   'declare a variable to hold a DataRelation object
				   Dim objRelation As DataRelation
				
				   'create a Relation object to link Books and Authors
				   objRelation = New DataRelation("BookAuthors", _
				                     objDataSet.Tables("Books").Columns("ISBN"), _
				                     objDataSet.Tables("Authors").Columns("ISBN"))
				   'and add it to the DataSet object's Relations collection
				   objDataSet.Relations.Add(objRelation)
				
				   'now do the same to link Books and Prices
				   objRelation = New DataRelation("BookPrices", _
				                     objDataSet.Tables("Books").Columns("ISBN"), _
				                     objDataSet.Tables("Prices").Columns("ISBN"))
				   objDataSet.Relations.Add(objRelation)
				
				   'now we're ready to display the contents of the DataSet object
				   'bind the collection of Tables to the first DataGrid on the page
				   dgrTables.DataSource = objDataSet.Tables
				   dgrTables.DataBind()
				
				   'bind the collection of Relations to the second DataGrid on the page
				   dgrRelations.DataSource = objDataSet.Relations
				   dgrRelations.DataBind()
				
				   'create a DataView object to use with the tables in the DataSet
				   Dim objDataView As New DataView()
				
				   'get the default view of the Books table into the DataView object
				   objDataView = objDataSet.Tables("Books").DefaultView
				   'and bind it to the third DataGrid on the page
				   dgrBooksData.DataSource = objDataView
				   dgrBooksData.DataBind()
				
				   'then do the same for the Authors table
				   objDataView = objDataSet.Tables("Authors").DefaultView
				   dgrAuthorsData.DataSource = objDataView
				   dgrAuthorsData.DataBind()
				
				   'and finally do the same for the Prices table
				   objDataView = objDataSet.Tables("Prices").DefaultView
				   dgrPricesData.DataSource = objDataView
				   dgrPricesData.DataBind()
				
				End Sub