! 6.5 两边简支开口柱壳在集中力作用下的大变形曲屈
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART ! 清除数据，不加载初始化文件
! （1）设置工程选项、分析类型、实常数、材料参数
/FILNAME, EX6.5 ! 定义工程文件名称
/PREP7 ! 加载前处理模块
SMRT, OFF ! 关闭智能化网格功能
/TITLE, EX6.5, SNAP-THROUGH BUCKLING OF A HINGED SHELL.
ANTYPE, STATIC ! 定义分析类型为静力分析
ET, 1, SHELL63, , 1 ! 定义第1类单元为弹性壳体单元SHELL63
R, 1, 6.350 ! 定义壳体厚度为6.350mm
MP, EX, 1, 3120.75 ! 定义第1类材料的弹性模量EX=3.12075 GPa
MP, NUXY, 1, 0.3 ! 定义第1类材料的泊松比为0.3
! （2）定义节点、关键点、面, 并将面剖分为面单元
R1 = 2540 ! 壳体中面曲率半径2540mm
L = 254 ! 壳体一半长度254mm
PI = 4*ATAN(1) ! Pi值
THETA = 0.1*180/PI ! 将0.1弧度转换为角度
CSYS, 1 ! 切换到柱面坐标系
N, 1, R1, 90 ! 在(R1, 90, 0)位置定义第1个节点
N, 2, R1, 90, L ! 在(R1, 90, L)位置定义第2个节点
K, 1, R1, 90 ! 在坐标(R1, 90, 0)处定义第1个关键点
K, 2, R1, (90-THETA) ! 在坐标(R1, 90-THETA, 0)处定义第2个关键点
K, 3, R1, 90, L ! 在坐标(R1, 90, L)处定义第3个关键点
K, 4, R1, (90-THETA), L ! 在坐标(R1, 90-THETA, L)处定义第4个关键点
ESIZE, , 2 ! 边界上单元剖分时剖分为2段
A, 1, 3, 4, 2 ! 过节点1, 3, 4, 2定义面
/View, 1, 1, 1, 1 ! 将窗口1的视点切换到等轴测方向
/PNUM, NODE, 1 ! 打开节点显示
AMESH, 1 ! 对1号面执行面单元剖分
NUMMRG, NODE ! 合并距离很近的节点
EPLOT ! 图形显示单元布置
! （3）施加位移边界条件
NSEL, S, LOC, Z, 0 ! 选择Z=0位置的节点
DSYM, SYMM, Z ! 定义关于Z轴(XY平面)的对称位移条件
NSEL, S, LOC, Y, 90 ! 选择Y=90度位置的节点
DSYM, SYMM, X ! 定义关于X轴(YZ平面)的对称位移条件
NSEL, S, LOC, Y, (90-THETA) ! 选择Y=90-THETA位置的节点
D, ALL, UX, , , , , UY, UZ ! 定义所有节点UX, UY和UZ位移被约束
NSEL, ALL ! 选择所有结点
F, 1, FY, -250 ! 由于对称, 只施加1/4荷载, 即250N
FINISH ! 退出前处理模块PREP7
! （4）在求解模块定义荷载后求解
/OUTPUT, SCRATCH ! 将输出重定向到文件SCRATCH, 以避免屏幕输出
/SOLU ! 进入求解模块
NLGEOM, ON ! 打开大变形选项
OUTRES, , 1 ! 输出所有荷载步的计算结果
NSUBST, 30 ! 按30个荷载子步计算
ARCLEN, ON, 4 ! 打开弧长求解开关, 最多保存4步计算值来进行插值计算
SOLVE ! 开始求解
FINISH ! 退出求解模块SOLU
/OUTPUT ! 关闭输出重定向
! （5）在时间历程后处理模块, 处理位移计算结果
/POST26 ! 进入时间历程后处理器Post26
NSOL, 2, 1, U, Y ! 保存1号节点的位移UY结果到第2个变量
NSOL, 3, 2, U, Y ! 保存2号节点的位移UY结果到第3个变量
PROD, 4, 1, , , LOAD, , , 4*250 ! 对第1个变量乘以总荷载4*250后保存到第4个变量
PROD, 5, 2, , , , , , -1 ! 对第2个变量执行改变位移正负号操作后保存到5号变量
PROD, 6, 3, , , , , , -1 ! 对第3个变量执行改变位移正负号操作后保存到6号变量
*GET, UY1, VARI, 2, EXTREM, VMIN ! 提取2号变量的最小值, 存入变量UY1
*GET, UY2, VARI, 3, EXTREM, VMIN ! 提取3号变量的最小值, 存入变量UY2
*STATUS, PARM
! （6）时间历程后处理模块, 会替荷载-变形曲线
PRVAR, 2, 3, 4 ! 列表显示第2, 3, 4号变量随时间的变化信息
/AXLAB, X, DEFLECTION (MM) ! 指定绘图坐标X轴上的文字标识
/AXLAB, Y, TOTAL LOAD (N) ! 指定绘图坐标Y轴上的文字标识
/GRID, 1 ! 显示X, Y方向的全部网格线
/XRANGE, 0, 35 ! X轴范围从0到35mm
/YRANGE, -500, 1050 ! Y轴范围从-500N到1050N
XVAR, 5 ! X轴上的变量是5号变量
PLVAR, 4 ! 图形显示荷载随着1号节点的-Y方向位移的变化情况
/NOERASE ! 不清除原来的图形
XVAR, 6 ! X轴上的变量是6号变量(2号节点的位移UY)
PLVAR, 4 ! 图形显示荷载随着2号节点的-Y方向位移的变化情况
/ERASE ! 设置在绘图前清除原有图形
FINISH
