!9.6 固支圆板的自由振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 设置工程选项,单元类型,材料参数
/FILNAME, EX9.6
/PREP7
SMRT,OFF
/TITLE, EX9.6 , NATURAL FREQUENCY OF A FLAT CIRCULAR PLATE WITH A CLAMPED EDGE
C*** FORMULAS FOR NATURAL FREQUENCY AND MODE SHAPE, BLEVINS, PAGE 241
ET,1,PLANE2,,,1
MP,EX,1,207E9
MP,PRXY,,0.3
MP,DENS,1,7801.6
! (2) 定义关键点,线和面,并将面划分为
K,1
K,2,0.4318
KGEN,2,1,2,1,,0.0127
L,1,2
L,3,4
LESIZE,ALL,,,10
ESIZE,,1
A,1,2,4,3
AMESH,1
! (3) 选择边界节点,施加位移约束
NSEL,R,LOC,X,0
D,ALL,UX
NSEL,ALL
DK,2,ALL,,,1
DK,4,UX,,,1
FINISH
! (4) 指定求解类型和求解方法后,开始模态分析的求解
/SOLU
ANTYPE,MODAL
MODOPT,SUBSP,9
EQSLVE,PCG
SOLVE
! (5) 提取频率计算结果
*GET,F1,MODE,1,FREQ
*GET,F2,MODE,2,FREQ
*GET,F3,MODE,3,FREQ
*Status, Parm
! (6) 定义数组变量,将计算结果及其与理论解的比值输出到文本文件
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'F (0,0) ','F (0,1) ','F (0,2) '
LABEL(1,2) = 'Hz','Hz','Hz'
*VFILL,VALUE(1,1),DATA,172.64,671.79,1505.7
*VFILL,VALUE(1,2),DATA,F1,F2,F3
*VFILL,VALUE(1,3),DATA,ABS(F1/172.64),ABS(F2/671.79),ABS(F3/1505.7)
/COM
/OUT, EX9_6, out
/COM,------------------- EX9.6 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.2,' ',F15.2,' ',1F10.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX9_6, out
