! 5.6 悬臂长板的大挠度弯曲
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! (1)设置工程参数、分析类型、单元类型、实常数和材料参数
/FILNAM, EX5.6(1)
/PREP7
/TITLE, EX5.6(1), LARGE DEFLECTION OF A CANTILEVERED PLATE.
/NOPR
SMRT, OFF
ANTYPE, STATIC
NLGEOM, ON
ET, 1, SHELL43
R, 1, 1
MP, EX, 1, 1800
MP, NUXY, , 0
! (2)定义关键点、线和面, 并剖分为面单元
K, 1
K, 2, 12
K, 3, 12, 1
K, 4, , 1
L, 1, 2
L, 3, 4
LESIZE, ALL, , , 2
ESIZE, , 1
A, 1, 2, 3, 4
/VIEW, 1, 0.61, -0.64, 0.47
/VUP, 1, Z
AMESH, 1
! (3)施加位移约束和荷载力
NSEL, S, LOC, X
D, ALL, ALL
NSEL, S, LOC, X, 12
CP, 1, ROTY, ALL
TORQ=15.708
F, 2, MY, TORQ
NSEL, ALL
FINISH
! (4)进入求解选模块, 设置求解选项后, 开始求解
/SOLU
AUTOTS, ON
NSUBST, 20
LNSRCH, ON
OUTPR, BASIC, LAST
OUTRES, ALL, ALL
SOLVE
FINISH
! (5)在后处理模块, 显示应力和位移计算结果
/POST1
RSYS, SOLU
SET, 1
SHELL, TOP
PRNSOL, S, COMP
PRNSOL, DOF
! (6)提取结果后存入变量
*GET, UX_N4, NODE, 4, U, X
*GET, UZ_N4, NODE, 4, U, Z
*GET, ROTY_N4, NODE, 4, ROT, Y
*GET, STRSS_N1, NODE, 1, S, X
! (7)保存计算结果
SAVE, TABLE_1
FINISH
! (8)重用改用有限应变层合壳单元SHELL181计算
/CLEAR, NOSTART
/FILNAM, EX5.6(2)
/PREP7
/TITLE, EX5.6(2), LARGE DEFLECTION OF A CANTILEVERED PLATE(SHELL181).
SMRT, OFF
/NOPR
ANTYPE, STATIC
NLGEOM, ON
ET, 1, SHELL181
R, 1, 1
RMORE, , , , , 10.0
MP, EX, 1, 1800
MP, NUXY, , 0
! (9)定义关键点、线和面, 并将面剖分为面单元
K, 1
K, 2, 12
K, 3, 12, 1
K, 4, , 1
L, 1, 2
L, 3, 4
LESIZE, ALL, , , 2
ESIZE, , 1
A, 1, 2, 3, 4
AMESH, 1
! (10) 施加位移约束和荷载力
NSEL, S, LOC, X
D, ALL, ALL
NSEL, S, LOC, X, 12
CP, 1, ROTY, ALL
TORQ=7.854
F, 2, MY, TORQ
NSEL, ALL
FINISH
! (11) 进入求解模块, 设置求解选项后, 开始求解
/SOLU
AUTOTS, ON
NSUBST, 10
LNSRCH, ON
OUTPR, BASIC, LAST
OUTRES, ALL, ALL
SOLVE
FINISH
! (12)在求解模块重启动分析
/SOLU
ANTYPE, , REST
F, 2, MY, TORQ*2
SOLVE
FINISH
! (13)在后处理模块, 显示计算结果
/POST1
RSYS, SOLU
SET, 2
SHELL, TOP
PRNSOL, S, COMP
PRNSOL, DOF
*GET, UX_N4, NODE, 4, U, X
*GET, UZ_N4, NODE, 4, U, Z
*GET, ROTY_N4, NODE, 4, ROT, Y
*GET, STRSS_N1, NODE, 1, S, X
! (14) 显示计算结果
*STATUS, PARM
Resume, TABLE_1
*STATUS, PARM
Finish
